Галактика в вопросах и ответах

Код: Выделить всё

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go

ALTER PROCEDURE [dbo].[spNapSetNRECMax](@TableName VARCHAR(200))
AS BEGIN
  DECLARE @SQL VARCHAR(8000)

  SELECT @SQL = '
    DECLARE @NREC VARBINARY(8)
    SELECT @NREC = MAX(F$NREC) FROM T$' + @TableName + '
    EXEC spNapSetNREC ''' + @TableName + ''', @NREC'
  EXEC(@SQL)
  --PRINT @SQL
END

Код: Выделить всё

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
go

ALTER PROCEDURE [dbo].[spNapSetNREC](@TableNameOrCode VARCHAR(80), @NewNREC VARBINARY(8))
AS
BEGIN
  DECLARE @I INT, @DbName VARCHAR(50), @NeedMax INT, @TableCode INT
  DECLARE @NREC0 VARBINARY(8), @NREC VARBINARY(8), @Base VARBINARY(2)
  SELECT
    @Base = CONVERT(VARBINARY(2), CONVERT(INT, SUBSTRING(@NewNREC, 1, 2)) & 0x8001)
  SELECT 
    @TableCode = dbo.fnTableCode(@TableNameOrCode),
    @DbName = UPPER(DB_NAME()), 
    @NeedMax=0, 
    @NREC0 = SUBSTRING(@Base, 1, 2) + SUBSTRING(0x000000000000, 1, 6), 
    @I = 0
  SELECT
    @NREC = @NREC0

  EXEC master..na_getnextnrec @DbName, @TableCode, @NREC OUTPUT, @NeedMax OUTPUT
  IF @NeedMax = 1 
    EXEC master..na_getnextnrecbymax @DbName, @TableCode, @NREC OUTPUT, @NeedMax OUTPUT, @NewNREC
  ELSE 
  IF @NREC >= @NewNREC
    PRINT 'spNAPSetNREC: NREC успешно приращен'
  ELSE
  BEGIN
    DECLARE @Diff BIGINT, @Msg VARCHAR(8000), @IMax BIGINT
    SELECT 
      @IMax = 1000000, 
      @Diff = CONVERT(BIGINT, @NewNREC) - CONVERT(BIGINT, @NREC)
    IF @Diff > @IMax BEGIN
      SELECT @Msg = 'spNAPSetNREC: приращение NREC на слишком большое значение (' + LTRIM(@Diff) + ')'
      RAISERROR(@Msg, 16, 1)
    END
    ELSE BEGIN
      PRINT 'spNapSetNREC: Вызываю na_getnextnrec в цикле...'
      --PRINT @NREC 
      --PRINT @NewNREC 

      WHILE @NREC < @NewNREC AND @I <= @IMax
      BEGIN
        --PRINT @NREC
        SELECT @NREC = @NREC0
        EXEC master..na_getnextnrec @DbName, @TableCode, @NREC OUTPUT, @NeedMax OUTPUT
        SELECT @I = @I + 1
      END
      --PRINT '@I = ' + LTRIM(@I)
      IF ISNULL(@NREC, 0) < @NewNREC 
      BEGIN
        SELECT @Msg = 'Ошибка в spNapSetNREC: ' + CHAR(10) + 
          'NREC не приращен до заданного значения. ' + 
          'Цикл прерван после ' + LTRIM(@I) + ' вызовов na_getnextnrec. ' + CHAR(10) + 
          'Для дополнительного приращения NREC повторно вызовите процедуру ' + 
          'spNapSetNREC.'
        RAISERROR(@Msg, 16, 1)
      END
    END
  END
  IF @NREC = @NewNREC PRINT 'spNapSetNREC: NREC успешно приращен.'
END