Галактика в вопросах и ответах

Код: Выделить всё

#include TxoApi.vih
#include ShowKau.vpp

// Указываем, что наш интерфейс реализует расчет идентификатора ТХО
#component "F_TXOAPI"
VipInterface Txo_TxoCalcIdent implements F_TXOAPI::ObjTxoIdentPlugin;
#component "F_TXOAPI"
// Простой интерфейс для обработки накладной
Interface Txo_TxoCalcIdent;

// Логическая таблица, описывает стуктуру накладной
create view DemoView
var
  CurTiDkGal : word;
  CurSoprDoc : comp;
  P1         : String;
  P2         : String;
as select
  *
from
  Oborot,
  Oborot OborotTemp(memory),
  Oborot Oborot1;
;


function GetInfo : string;
{
   GetInfo := 'Объединение однотипных проводок';
}

function ParamMaster : string;
{
   Message(''#3'здесь должен быть вызов окошка, чтобы помочь пользователю'#13+
           ''#3'заполнить строку дополнительных параметров идентификатора:'#13+
           ''#3'[Param1:"xxx"][Param2:"yyy"]');
   ParamMaster := '[Param1:"xxx"][Param2:"yyy"]';
}


procedure StoreCycles(hTxo : longint; buf : TTxoApiInfoDoc);
{
   CurTiDkGal := buf.TiDkGal;
   CurSoprDoc := buf.cSoprDoc;
	var isNew:boolean;
	isNew:=True;
   _loop Oborot where ((CurTiDkGal == Oborot.Tidk and CurSoprDoc==Oborot.cSoprDoc))
     {
		 //проверка однотипности проводки по счету,субсчету, КАУ1..6 и подразделению
		 _loop OborotTemp
			{
				isNew:=True;
				if   Oborot.Scheto = OborotTemp.Scheto and
				   Oborot.SubOsSch = OborotTemp.SubOsSch and
 				   Oborot.KauOs[1] = OborotTemp.KauOs[1] and
				   Oborot.KauOs[2] = OborotTemp.KauOs[2] and
				   Oborot.KauOs[3] = OborotTemp.KauOs[3] and
				   Oborot.KauOs[4] = OborotTemp.KauOs[4] and
				   Oborot.KauOs[5] = OborotTemp.KauOs[5] and
				   Oborot.KauOs[6] = OborotTemp.KauOs[6] and
				   Oborot.KodSpo   = OborotTemp.KodSpo   and
                   Oborot.SchetK   = OborotTemp.SchetK   and
				   Oborot.SubSchK  = OborotTemp.SubSchK  and
				   Oborot.KauKs[1] = OborotTemp.KauKs[1] and
				   Oborot.KauKs[2] = OborotTemp.KauKs[2] and
				   Oborot.KauKs[3] = OborotTemp.KauKs[3] and
				   Oborot.KauKs[4] = OborotTemp.KauKs[4] and
				   Oborot.KauKs[5] = OborotTemp.KauKs[5] and
				   Oborot.KauKs[6] = OborotTemp.KauKs[6] and
				   Oborot.KodSpK   = OborotTemp.KodSpK   and
				   Oborot.DatOb    = OborotTemp.DatOb    and
 				   Oborot.KodValut = OborotTemp.KodValut
				   {
					 isNew:=False;
				     break;
				   }
			}
		   if isNew
		    {
					   OborotTemp.buffer:=Oborot.buffer;
					   insert current OborotTemp;
			}
		    else
			{
		             OborotTemp.SumOb:=OborotTemp.SumOb+Oborot.SumOb;
			         OborotTemp.SumValut:=OborotTemp.SumValut+Oborot.SumValut;
		             update current OborotTemp;
			}
		 delete current Oborot;
	 }
   _loop OborotTemp
    {
		Oborot.buffer:=OborotTemp.buffer;
		insert current Oborot;
	}
}
end.