фильтр кау

[Gameus_]

Добрый день, нужен совет
в своем интерфейсе выбираем счет/субсчет для фильтрации проводок. Сейчас необходимо расширить функционал фильтрации, добавив еще фильтры по двум уровням КАУ. Подскажите плиз, с какой стороны подойти к проблеме.. (для разных счетов на одном и том же уровне кау могут быть ссылки на разные таблицы)

[edward_K]

Если один счет субсчет - то проблем вообще нет. - тянетесь до buhschet и смотрите какие там аналитики.
Ест.при перевыборе сбрасываете фильтр. Выбор удобно реализовать через объект GetKAu -ищите на форуме.
Если несколько счетов/субсчтоев, то можно попросить пользователя самостоятельно задавать аналитики фильтрации или посмотрите интерактивный во фро.

[Gameus_]

счет/субсчет будет один. пытаюсь использовать getkau

Код: Выделить всё

#include galnet.ccm
#include galnet.csc
end;
#include getkau.vih


interface get_oborot '‚лЎ®а Їа®ў®¤®Є' cyan,DoAccept;

var
  iGetKau: GetKau;    //объектный фейс для выбора аналитики по коду.
  lMarker: longint;   //хэндл маркера, в который свалятся помеченные пользователем аналитики
  MarkerName: String; //имя маркера - для каждого кода аналитики - свой, получается из iGetKau.GetMarkerNam
......
var KodGr: word; 
  KodGr := 3; //Код аналитики для persons
  var cSelected: comp;
  iGetKau.GetCodeKau(2, KodGr, cSelected); //собсно запуск интерфейса множественного выбора
  MarkerName := iGetKau.GetMarkerName(KodGr); //получаем имя маркера
  lMarker := initmarker(MarkerName, 8, 10, 100, false); //создаем маркер и читаем из дск файла то, что напомечал пользователь  

получаю ошибку:
ExObjifcNoLoad(ExRef)
Ошибка загрузки объекта из ресурсного файла (GetKau)

это у меня getkau.vih старый или не то че-то делаю ?
файл проекта:

Код: Выделить всё

#define ComponentVersion
#make "get_oborot.vip"
...

[edward_K]

скорей всего старый файл - поищите в frm на 810.
У вас почему то нет компонентной принадлежности в ошибке а должна бы.
И
#include galnet.ccm
#include galnet.csc
end;
лучше держать в проекте.

[Gameus_]

в frm нет getkau.vih - не могли бы вы поделиться последней версией ?

[edward_K]

Вообще еще лог компиляции посмотрите повнимательней.

Код: Выделить всё

//------------------------------------------------------------------------------
//                                                      (c) Корпорация ГАЛАКТИКА
//------------------------------------------------------------------------------
// Галактика 5.8 - Бухгалтерский контур
// Обьектный интерфес выбора КАУ
//------------------------------------------------------------------------------

#ifndef _GetKau_vih_Included
#define _GetKau_vih_Included

#ifdef ComponentVersion
#Component "F_GetAn"
#end

!-------------------------------------------------------------------------------
#doc
Обьектный интерфес выбора КАУ
#end
ObjInterface ObjGetKau;
!-------------------------------------------------------------------------------
  #doc
  Возвращает имя маркера для аналитики с номером wKau.
  #end
  function GetMarkerName
          (     wKau     : word  // код КАУ (таблица КАУ)
          ) : string;

!-------------------------------------------------------------------------------
  #doc
  Запуск интерфейса выбора аналитики одного уровня.<br>
  Возвращает количество выбранных записей.
  #end
  //<b>wIntMode</b> режим выбора (см.GloConst.inc)<br>
  //<b>wKau</b> код КАУ (таблица КАУ) (см. KauConst.inc).
  //Возвращает код <b>элементарной</b> аналитики для <b>Наборов</b> и <b>Обобщенных аналитик</b>
  //(для остальных возвращается как был на входе)<br>
  //<b>cKau</b> выбранное значение (NRec) <b>элементарной</b> аналитики<br>
  function GetCodeKau
          (     wIntMode : word; // режим выбора          (см.GloConst.inc)
            var wKau     : word; // код КАУ (таблица КАУ) (см. KauConst.inc).
                                 // Возвращает код ЭЛЕМЕНТАРНОЙ Аналитики для
                                 // Наборов и Обобщенных (для остальных
                                 // возвращается как был на входе)
            var cKau     : comp  // выбранный NRec ЭЛЕМЕНТАРНОЙ Аналитики
          ) : longint;           // возвращает количество выбранных записей

!-------------------------------------------------------------------------------
  #doc
  Удалить все фильтры выбора.
  #end
  procedure ClearFilter;
!-------------------------------------------------------------------------------
  #doc
  Установить фильтр выбора.
  #end
  //<b>wKau</b> код КАУ (таблица КАУ)<br>
  //<b>cKau</b> NRec КАУ
  procedure SetFilter
          (     wKau     : word; // код КАУ (таблица КАУ)
                cKau     : comp  // NRec КАУ
          );
!-------------------------------------------------------------------------------
end;
!-------------------------------------------------------------------------------
VipInterface GetKau implements ObjGetKau #Licensed_Free;
!-------------------------------------------------------------------------------
#end // _GetKau_vih_Included

[Gameus_]

Спасибо огромное - vih действительно старый был.